build.gradle

plugins {
    id 'java-library'
    id 'net.neoforged.moddev' version '2.0.72'
}

version = "1.3"
group = "net.mcreator.minecraft.link" // http://maven.apache.org/guides/mini/guide-naming-conventions.html
base.archivesName = "mcreator_link"

java.toolchain.languageVersion = JavaLanguageVersion.of(21)

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8' // Use the UTF-8 charset for Java compilation
}

neoForge {
    version = "21.4.47-beta"

    runs {
        client {
            client()
        }
        server {
            server()
        }
    }

    mods {
        mcreatorlink {
            sourceSet sourceSets.main
        }
    }
}

dependencies {
    jarJar(implementation("com.fazecast:jSerialComm")) {
        version {
            strictly '[2.7, 2.8)'
            prefer '2.7.0'
        }
    }

    additionalRuntimeClasspath 'com.fazecast:jSerialComm:2.7.0'
}

javadoc {
    source sourceSets.main.allJava
}

tasks.register('copyModIntoFinalBuild', Copy) {
    def projectVersion = version
    from('build/libs/')
    include('mcreator_link-' + version + '.jar')
    into('build/export/')
    rename { "MCreator Link ${projectVersion} [1.21.4].jar" }

    dependsOn jarJar
    dependsOn build
}

tasks.register('exportArduinoLibrary', Zip) {
    archiveFileName = "MCreator Link " + project.version + " Arduino Library.zip"
    destinationDirectory = file('build/export/')
    from(files('./arduino'))
}

tasks.register('exportJavadoc', Copy) {
    from('build/docs/javadoc')
    into('docs/')

    dependsOn javadoc

    group = 'mcreatorlink'
}

tasks.register('exportAll') {
    group = 'mcreatorlink'

    dependsOn copyModIntoFinalBuild
    dependsOn exportArduinoLibrary
}