settings.gradle.kts

rootProject.name = "spc-site"

enableFeaturePreview("TYPESAFE_PROJECT_ACCESSORS")
//enableFeaturePreview("VERSION_CATALOGS")

pluginManagement {

    val toolsVersion: String by extra
    val snarkVersion: String by extra

    repositories {
        maven("https://repo.kotlin.link")
        mavenCentral()
        gradlePluginPortal()
    }

    plugins {
        id("space.kscience.gradle.project") version toolsVersion
        id("space.kscience.gradle.mpp") version toolsVersion
        id("space.kscience.gradle.jvm") version toolsVersion
        id("space.kscience.gradle.js") version toolsVersion
        id("space.kscience.snark") version snarkVersion
    }
}

dependencyResolutionManagement {

    val toolsVersion: String by extra

    repositories {
        maven("https://repo.kotlin.link")
        mavenCentral()
    }

    versionCatalogs {
        create("npmlibs") {
            from("space.kscience:version-catalog:$toolsVersion")
        }
    }
}

val snarkProjectDirectory = File("../snark")
if(snarkProjectDirectory.exists()) {
    includeBuild("../snark")
}