Triples for number of vertices

[1ec5]

In OSM and OHM, we can easily access all the vertices of a way, but sometimes we need to access just the first or last vertex. For example, this query uses the first and last vertices to calculate the way’s sinuosity:

PREFIX osmway: <https://www.openstreetmap.org/way/>
PREFIX osmkey: <https://www.openstreetmap.org/wiki/Key:>
PREFIX osmrel: <https://www.openstreetmap.org/relation/>
PREFIX ogc: <http://www.opengis.net/rdf#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX osm2rdf: <https://osm2rdf.cs.uni-freiburg.de/rdf#>
PREFIX osm2rdfmember: <https://osm2rdf.cs.uni-freiburg.de/rdf/member#>
PREFIX geof: <http://www.opengis.net/def/function/geosparql/>
PREFIX geo: <http://www.opengis.net/ont/geosparql#>
SELECT ?river ?channel_length ?downvalley_length ?sinuosity_index WHERE {
  {
    SELECT ?river ?source_geometry ?mouth_geometry WHERE {
      # Compute the last vertex position of each river
      {
        SELECT ?river (COUNT(?vertex) - 1 AS ?last_pos) WHERE {
          ?river osmkey:waterway "river" .
          osmrel:1116270 ogc:sfIntersects ?river .
          ?river osmway:node ?vertex .
        }
        GROUP BY ?river
      }
      ?river osmkey:waterway "river" .
      osmrel:1116270 ogc:sfIntersects ?river .
      ?river osmway:node [ osmway:node ?first_node ; osm2rdfmember:pos "0"^^xsd:int ] .
      ?first_node geo:hasGeometry/geo:asWKT ?source_geometry .
      ?river osmway:node [ osmway:node ?last_node ; osm2rdfmember:pos ?last_pos ] .
      ?last_node geo:hasGeometry/geo:asWKT ?mouth_geometry .
    }
  }
  ?river osm2rdf:length ?channel_length .
  BIND (geof:distance(?source_geometry, ?mouth_geometry) AS ?downvalley_length)
  BIND (?channel_length / ?downvalley_length AS ?sinuosity_index)
}
ORDER BY DESC(?sinuosity_index)

We know the position of the first vertex is zero, but we need an aggregate subquery just to determine the last position. This is much less memorable and perhaps less performant than the equivalent OverpassQL query, which can compare a vertex’s position to count_members() or count_distinct_members(). (A closed or self-intersecting way references a node more than once.) A triple about the number of vertices seems like a good complement to the existing rdf:facts triple.

These Overpass evaluators can also get the number of members in a relation, which could be convenient in some cases. However, count_distinct_by_role(…) can’t be expressed as a triple, so a subquery would be necessary anyways.