Default values in Listings/Mappings in combination with Subtypes

[Gr33zy]

Hello,
I try to migrate a large project using PKL. As part of the project, I have a scenario where a class hierarchy is defined:
Parent: Foo
Subtypes: Bar, Baz
So Bar and Baz have some common properties but each of those types also have a set of specific properties. In addition, there is a container class which contains, among other properties, a list of Foo. It looks something like this:

• Foo.pkl

  open module Foo
  
  name: String
  
  commonProperty: String
  
  // other properties
  // ...

• Bar.pkl

  extends "Foo.pkl"
  
  barSpecificProperty: Int
  
  // other Bar specific properties
  // ...

• Baz.pkl

  extends "Foo.pkl"
  
  bazSpecificProperty: Boolean
  
  // other Baz specific properties
  // ...

• FooContainer.pkl

  import "Foo.pkl"
  
  fooList: Listing<Foo>
  
  // other properties
  // ...

Now, I tried to create a FooContainer adding different Foo types while making use of the default property of Listings:

• foos.pkl

  amends "FooContainer.pkl"
  
  import "Bar.pkl"
  import "Baz.pkl"
  import "Foo.pkl"
  
  fooList = new Listing<Foo> {
    default {
      commonProperty = "common"
    }
    new { // Works fine
      name = "Foo1"
    }
    new Foo { // ERROR: Tried to read property `commonProperty` but its value is undefined.
      name = "Foo2"
    }
    new Bar { // ERROR: Tried to read property `commonProperty` but its value is undefined.
      name = "Bar"
      barSpecificProperty = 0
    }
    new Baz { // ERROR: Tried to read property `commonProperty` but its value is undefined.
      name = "Bar"
      bazSpecificProperty = false
    }
  }

I noticed, that as soon as I specify a concrete type like new Bar, the commonProperty will not be set by the Listing's default property. Is there any way to achieve something like this?

[HT154]

This is a limitation of Listing/Mapping defaults and is (as of recently) covered in the language reference here: https://pkl-lang.org/main/current/language-reference/index.html

One approach that works provided that you do not need to override commonProperty in specific Listing elements is to amend in that property afterwards using a member predicate:

amends "FooContainer.pkl"

import "Bar.pkl"
import "Baz.pkl"
import "Foo.pkl"

fooList = new {
  new {
    name = "Foo1"
  }
  new Foo {
    name = "Foo2"
  }
  new Bar {
    name = "Bar"
    barSpecificProperty = 0
  }
  new Baz {
    name = "Bar"
    bazSpecificProperty = false
  }
} {
  [[true]] {
    commonProperty = "common"
  }
}

[discount-elf]

Oof, wished defaults worked here. Amend following doesn't work for my use case, and I can't come up with a better way to do value injection for the children.

[bioball]

Can you clarify? What is it about amends that doesn't work for you?

[discount-elf]

// Snippet from pel.Container
local parent = this

// Rendering this type requires the SomeThing value
hidden res: ContainerResourceResolvable = new {
  Id = parent.Id
  Type = parent.Type
  SomeThing = parent.SomeThing
}


// Template
SomeThing = "example-thing"

Resources {
  // Would be best if this were in the module definition
  default {
    SomeThing = module.Something
  }

  local container = new pel.Container {
    Id = "pel-con"
    Name = "container"
  }
  container

  new pel.ItemKind1 {
    Id = "pel-item1"
    Name = "fruitbat"
    Container = container.res.ResolvableProperty
  }

  new pel.ItemKind2 {
    Id = "pel-item2"
    Name = "snarf"
    Container = container.res.ResolvableProperty
  }
}

I am constructing an object from a list member. This object is required for a property of another list member (the app needs a reference upstream for dependency resolution). This object requires a property to be captured from the enclosing module (trying to hide this from the user so the value is only present in the module). Amending DOES set the property on the list members but of course any generated objects from those children are untouched.

Probably I can look at all the list member properties, and if the value is of a given type I can set the missing field. So I guess I am not stuck any way.