build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {
    repositories {
        google()
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:4.2.2'
        classpath 'org.jacoco:org.jacoco.core:0.8.6'
        classpath 'org.jetbrains.kotlin:kotlin-gradle-plugin:1.5.20'

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

allprojects {
    repositories {
        google()
        mavenCentral()
    }
    tasks.withType(Test) {
        testLogging {
            exceptionFormat "full"
            showCauses true
            showExceptions true
            showStackTraces true
            events = ["passed", "skipped", "failed"]
        }
        reports {
            html.enabled = true
            junitXml.enabled = true
            junitXml.outputPerTestCase = true
        }
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

task testAll(dependsOn: ['app:testDebugUnitTest', 'app:connectedDebugAndroidTest', 'app:uninstallDebug', 'apptest:connectedDebugAndroidTest']) {
    group = 'orchestration'
    description = "Run all tests"
}

gradle.projectsEvaluated {
    project(":apptest") {
        connectedDebugAndroidTest.dependsOn project(":app").installDebug
    }
    project(":app") {
        installDebug.mustRunAfter project(":app").connectedDebugAndroidTest
    }
}