build.gradle

plugins {
    id 'idea'
    id 'java'
    id 'java-library'
}


// 所有模块/项目的通用配置
allprojects {
    group = GROUP_ID
    version = VERSION

    apply plugin: 'maven-publish'
    apply plugin: 'signing'

    // 指定JDK版本
    sourceCompatibility = JavaVersion.VERSION_11
    targetCompatibility = JavaVersion.VERSION_11
    // 指定编码格式
    [compileJava, compileTestJava, javadoc]*.options*.encoding = 'UTF-8'

    tasks.withType(JavaCompile) {
        options.compilerArgs << "-Xlint:unchecked" << "-Xlint:deprecation"
    }

    tasks.withType(Javadoc) {
        options.addStringOption('Xdoclint:none', '-quiet')
        options.addStringOption('encoding', 'UTF-8')
        options.addStringOption('charSet', 'UTF-8')
    }

    // Java编译任务依赖处理资源的任务
    compileJava.dependsOn(processResources)

    //maven仓库
    repositories {
        mavenLocal()
        maven { url "https://maven.aliyun.com/repository/public" }
        maven { url "https://maven.aliyun.com/repository/spring" }
        maven { url "https://maven.aliyun.com/repository/spring-plugin" }
        maven { url 'https://maven.aliyun.com/repository/gradle-plugin' }
        maven { url "https://repo.spring.io/release" }
        maven { url "https://repo.spring.io/milestone" }
        mavenCentral()
    }
}


configure(subprojects - project(":gear4j-bom")) {
    apply plugin: "idea"
    apply plugin: "java"
    apply plugin: "java-library"
    apply from: "${rootProject.projectDir}/gradle/publish.gradle"

    ext {
        springBootVersion = "2.6.9"
        lombokVersion = "1.18.24"
    }

    // 子项目依赖，类似于在父maven的dependencies
    dependencies {
        // import BOM.
        api platform(project(':gear4j-bom'))

        compileOnly "jakarta.servlet:jakarta.servlet-api"
        compileOnly "org.springframework.boot:spring-boot-starter-web"
        compileOnly "com.baomidou:mybatis-plus-extension"

        compileOnly "com.google.code.findbugs:jsr305"
        compileOnly "io.swagger:swagger-annotations"
        compileOnly "io.swagger.core.v3:swagger-annotations"

        annotationProcessor "org.springframework.boot:spring-boot-configuration-processor:${springBootVersion}"
        testCompileOnly "com.google.code.findbugs:jsr305"
        testImplementation 'org.springframework.boot:spring-boot-starter-test'

        // lombok
        annotationProcessor "org.projectlombok:lombok:${lombokVersion}"
        compileOnly "org.projectlombok:lombok:${lombokVersion}"
        testAnnotationProcessor "org.projectlombok:lombok:${lombokVersion}"
        testCompileOnly "org.projectlombok:lombok:${lombokVersion}"
    }


    configurations.all {
        //移除org.json:json
        exclude module: 'json'
        exclude module: 'hutool-http'
        //升级spring-beans 版本
//        resolutionStrategy.eachDependency { DependencyResolveDetails details ->
//            if (details.requested.group == 'org.springframework:spring-beans') {
//                details.useVersion '5.3.21'
//            }
//        }
    }

    test {
        useJUnitPlatform()
        testLogging {
            events "passed", "skipped", "failed"
        }
    }
}