Option to show a diff buffer when creating a pull request

[jdormit]

One of my favorite features of Magit is that a diff buffer pops up when you go to write a commit message. It would be awesome if Forge had an option to enable similar behavior when writing a pull request. I have a function in my personal config to do this:

(defun forge-diff-for-pr ()
  (interactive)
  (let ((target forge--buffer-base-branch)
        (source forge--buffer-head-branch))
    (magit-diff-range (format "%s..%s" source target))))

(add-hook 'forge-create-pullreq-hook #'forge-diff-for-pr)

This works fine for me, but I'm wondering if there is enough demand for this to make it worth including in Forge itself? Or does this functionality already exist and I just missed it?

[pkryger]

This is actually something I've been missing too. Using default magit-commit-show-diff I got used to seeing what is being committed and killing/yanking symbol names from such a diff buffer. So this saved a few keystrokes (and mental load) in such a scenario!

However, I have been missing a couple things:

• I wanted the diff buffer to disappear as soon as I am done with post, either after submitting it or after cancelling it. I want the window configuration to be restored as well.
• I want to be able to switch that off, so decided to add extra check for magit-commit-show-diff, before creating diff for PR.

@tarsius do you think this is something you want to include in future release? Would you be interested in reviewing a PR? I am happy to cut a one, but will appreciate your input so that it won't step over your future plans.

Using @jdormit solution as a starting point I came up with this:

(defvar-local pk/forge--pullreq-diff-buffer-winconf nil
  "A cons in form (BUFFER . WINCONF).
The BUFFER is diff buffer created for a pull-request, while
WINCONF is a windows configuration prior to displaying
new-pullreq buffer.")

(defun pk/forge--diff-for-pullreq ()
  "Show diff for the current pull-request."
  (interactive)
  (when-let* ((magit-commit-show-diff)
              (target forge--buffer-base-branch)
              (source forge--buffer-head-branch)
              (pullreq-buffer (current-buffer)))
    (let ((diff-buffer (magit-diff-range (format "%s..%s" source target))))
      (with-current-buffer pullreq-buffer
        (setq pk/forge--pullreq-diff-buffer-winconf
              (cons diff-buffer
                    (cdr pk/forge--pullreq-diff-buffer-winconf)))))))

(defun pk/forge--store-winconf (orig-fun &rest args)
                                        ; checkdoc-params: (orig-fun args)
  "Store windows configuration."
  (let ((winconf (current-window-configuration))
        (buffer (apply orig-fun args)))
    (with-current-buffer buffer
      (setq pk/forge--pullreq-diff-buffer-winconf (cons nil winconf)))
    buffer))

(defun pk/forge--kill-diff-buffer-restrore-winconf (orig-fun &rest args)
                                        ; checkdoc-params: (orig-fun args)
  "Kill a buffer set in `pk/forge--pullreq-diff-buffer'."
  (pcase-let ((`(,diff-buffer . ,winconf)
                 pk/forge--pullreq-diff-buffer-winconf))
      (apply orig-fun args)
      (when diff-buffer
        (with-current-buffer diff-buffer
          (magit-mode-bury-buffer 'kill))
        (when winconf
          (set-window-configuration winconf)))))

(add-hook 'forge-create-pullreq-hook #'pk/forge--diff-for-pr)

(advice-add 'pk/forge--prepare-post-buffer
            :around #'pk/forge--store-winconf)
(advice-add 'forge-post-cancel
            :around #'pk/forge--kill-diff-buffer-restrore-winconf)
(advice-add 'forge-post-submit
            :around #'pk/forge--kill-diff-buffer-restrore-winconf)

It's not that pretty, as advices are involved and internal forge--prepare-post-buffer is involved. However, with current forge version (as of beginning of 2025), I made these choices, considering as well:

1. Capturing windows configuration in forge-create-pullreq-hook is too late, as windows configuration has been changed already (i.e., when forge asks whether or not to discard a draft). I couldn't find a hook that is called when the "new-pullreq" buffer has been created but window configuration hasn't been changed yet.
2. I considered using forge-post-submit-callback-hook to close the diff buffer and restore windows configuration, however I couldn't find a counterpart for forge-post-cancel. I preferred to keep the same mechanics for both cases.
3. I considered using forge--cancel-post-function and forge--submit-post-function instead of advices. This could eliminate a need to keep the buffer local variable pk/forge--pullreq-diff-buffer-winconf as all state could be captured in closures, but I decided not to for the following reasons. First I find advices, despite all their drawbacks, kind of idiomatic to Emacs - at least in my experience I encounter them quite often; definitely more often than calling a function stored in buffer local variable. Second was to keep the solution using smaller number of mechanisms and I couldn't figure out not using advice for point 2.

[tarsius]

Please stick to using your advises for now. I plan to make some changes to the pull-request creation process but so far I haven't worked out any details and there also is no timeline. Adding a feature to automatically show a diff now could lock me into providing in a certain way, making the other improvements harder. So for now I don't want to add this feature, but it generally makes sense to me too.