.vimrc-2022

" VARIABLES
" =========

" Plugins variables
" -----------------

let g:netrw_banner = 0
let g:netrw_liststyle = 0

" vim-markdown
let g:vim_markdown_folding_disabled = 1
let g:vim_markdown_frontmatter = 1
let g:vim_markdown_auto_insert_bullets = 0
 
" vim-javascript
let g:javascript_plugin_jsdoc=1

" editorconfig-vim
let g:EditorConfig_exclude_patterns = ['fugitive://.*']

" ack.vim
let g:ackhighlight = 1

" fzf
let g:fzf_layout = { 'window': { 'width': 0.9, 'height': 0.9 } }

" Customize fzf colors to match your color scheme
" - fzf#wrap translates this to a set of `--color` options
let g:fzf_colors =
\ { 'fg':      ['fg', 'Normal'],
  \ 'bg':      ['bg', 'Normal'],
  \ 'hl':      ['fg', 'Comment'],
  \ 'fg+':     ['fg', 'CursorLine', 'CursorColumn', 'Normal'],
  \ 'bg+':     ['bg', 'CursorLine', 'CursorColumn'],
  \ 'hl+':     ['fg', 'Statement'],
  \ 'info':    ['fg', 'PreProc'],
  \ 'border':  ['fg', 'Number'],
  \ 'prompt':  ['fg', 'Conditional'],
  \ 'pointer': ['fg', 'Exception'],
  \ 'marker':  ['fg', 'Keyword'],
  \ 'spinner': ['fg', 'Label'],
  \ 'header':  ['fg', 'Comment'] }


" CoC
let g:coc_global_extensions = [
  \ 'coc-snippets',
  \ 'coc-tsserver',
  \ 'coc-eslint',
  \ 'coc-html', 
  \ 'coc-css', 
  \ 'coc-json', 
  \ 'coc-prettier', 
  \ ]

" Syntastic
let g:syntastic_sass_checkers=["sasslint"]
let g:syntastic_scss_checkers=["sasslint"]
" Add below variable in a local .vimrc
" let g:sass_lint_config = '/path/to/.sass-lint.yml'

" markdown-preview
let g:mkdp_auto_start = 0
let g:mkdp_auto_close = 1
let g:mkdp_browser = 'Firefox Developer Edition'

" emmet-vim
let g:user_emmet_leader_key='<C-E>'
let g:user_emmet_install_global = 0

" vimwiki
let g:vimwiki_list = [{'path': '~/notebook/notes',
                      \ 'syntax': 'markdown', 'ext': '.md', 'links_space_char': '-'}]
let g:vimwiki_global_ext = 0


" PLUGINS
" =======

" Plugin manager => https://github.com/junegunn/vim-plug
call plug#begin('~/.vim/plugged')

" Text objects
" ------------

Plug 'kana/vim-textobj-user'
Plug 'kana/vim-textobj-entire'
Plug 'kana/vim-textobj-line'
Plug 'michaeljsmith/vim-indent-object'
Plug 'whatyouhide/vim-textobj-xmlattr'
Plug 'jceb/vim-textobj-uri'
Plug 'wellle/targets.vim'

" Language support/syntax highlighting
" ------------------------------------

Plug 'pangloss/vim-javascript', { 'for': ['js', 'jsx'] }
Plug 'mustache/vim-mustache-handlebars', { 'for': ['mustache', 'hbs'] }
Plug 'plasticboy/vim-markdown', { 'for': ['md', 'markdown'] }
Plug 'neoclide/coc.nvim', {'branch': 'release'}
Plug 'mattn/emmet-vim'
Plug 'udalov/kotlin-vim'
Plug 'jparise/vim-graphql'

" Syntax checkers/linters
" -----------------------

Plug 'editorconfig/editorconfig-vim'
Plug 'scrooloose/syntastic'
Plug 'gcorne/vim-sass-lint'

" Buffer management
" -----------------

Plug 'arithran/vim-delete-hidden-buffers'
Plug 'tpope/vim-eunuch'

" UI/UX Extensions
" ----------------

Plug '~/.fzf' " Should have been installed with git seperately in home folder.
Plug 'junegunn/fzf.vim'
Plug 'airblade/vim-gitgutter'
Plug 'tpope/vim-fugitive'
Plug 'tpope/vim-rhubarb'
Plug 'mileszs/ack.vim'
Plug 'iamcco/markdown-preview.nvim', { 'do': 'cd app & npm install'  }
Plug 'mzlogin/vim-markdown-toc'
Plug 'romainl/vim-cool'

" Extensions
" ----------

Plug 'vim-scripts/matchit.zip'
Plug 'tpope/vim-surround'
Plug 'tpope/vim-unimpaired'
Plug 'tpope/vim-commentary'
Plug 'tpope/vim-repeat'
Plug 'vim-scripts/ReplaceWithRegister'
Plug 'junegunn/vim-easy-align'

" Applications
" ------------

Plug 'vimwiki/vimwiki'

call plug#end()





" FUNCTIONS
" =========

function MyVimEnter()
    if argc() == 1 && argv(0) == '.'
      execute "Files"
    endif

    return
endfunction

" netrw functions
" -------------

function NetrwMappings()
	nnoremap <buffer> <C-h> :wincmd h<cr>
	nnoremap <buffer> <C-j> :wincmd j<cr>
	nnoremap <buffer> <C-k> :wincmd k<cr>
	nnoremap <buffer> <C-l> :wincmd l<cr>
endfunction

" fzf functions
" -------------

function! s:list_buffers()
  redir => list
  silent ls
  redir END
  return split(list, "\n")
endfunction

function! s:delete_buffers(lines)
  execute 'bwipeout' join(map(a:lines, {_, line -> split(line)[0]}))
endfunction

" CoC functions
" -------------

function! s:show_documentation()
	if (index(['vim','help'], &filetype) >= 0)
		execute 'h '.expand('<cword>')
	else
		call CocAction('doHover')
	endif
endfunction





" SETTINGS
" ========

" General configuration
" ---------------------

set nocompatible
language en_US.utf-8
set encoding=utf-8
set backspace=indent,eol,start
set hidden
set history=1000
set exrc


" User Interface
" --------------

colorscheme solarized8
set background=dark
let g:solarized_diffmode="high"

set title
set laststatus=2
set number
set splitright
set splitbelow
set listchars=tab:▸\ ,space:·,trail:·,eol:¬
set cursorline
set colorcolumn=+1
set termguicolors
set guifont=Victor\ Mono:h16
set wildmenu
set showmatch
syntax enable

" Turn on omni completion
filetype plugin on
set omnifunc=syntaxcomplete#Complete

" Cursor behaviour
set guicursor=n-v-c-ci-i:block-Cursor-blinkwait1-blinkon150-blinkoff150

" Don't offer to open certain files/folders
set wildignore+=*.bmp,*.gif,*.ico,*.jpg,*.png,*.ico
set wildignore+=*.pdf,*.psd
set wildignore+=*.map,*.min.css,*.min.css
set wildignore+=*/node_modules/*,*/bower_components/*

" Outside vim file changes tracking
set updatetime=250
set autoread 


" Indentation
" -----------

set autoindent
filetype plugin indent on

set noexpandtab
set tabstop=4
set shiftwidth=4
set softtabstop=4
set shiftround


" Search
" ------

set incsearch 
set hlsearch
set ignorecase
set smartcase


" Swap and backup file strategy
" -----------------------------

set directory=$HOME/.vim-directory//
set nobackup
set nowritebackup





" HIGHLIGHTS
" ==========

" Italicised comments and attributes.
highlight Comment cterm=italic gui=italic guifg=#5f87df
highlight htmlArg cterm=italic gui=italic guifg=#af8700

highlight StatuslineFilename cterm=bold ctermfg=136 gui=bold guifg=#b58900
highlight StatuslineCustom ctermfg=252 ctermbg=238 guifg=#D9D9D9 guibg=#565656





" MAPPINGS
" ========

let mapleader = "\<Space>"

nnoremap <leader>ev :tabnew ~/.vimrc<CR>
nnoremap <leader>rv :source $MYVIMRC<CR>

nnoremap j gj
nnoremap k gk

" <S-arrow> to resize splits (not optimal yet).
nnoremap <S-right> :vertical resize +2<CR>
nnoremap <S-left>  :vertical resize -2<CR>
nnoremap <S-down>  :resize -2<CR>
nnoremap <S-up>    :resize +2<CR>

nnoremap <leader>w :write!<cr>
nnoremap <leader>q :quit<cr>

" Easier window navigation.
map <C-h> <C-w>h
map <C-j> <C-w>j
map <C-k> <C-w>k
map <C-l> <C-w>l

" Easilly search for things.
nnoremap <silent> <C-p> :Files<CR>
nnoremap <silent> gb :Buffers<CR>
nnoremap <silent> gl :BLines<CR>
nnoremap <leader>f :Ack! "
vnoremap <leader>f y:Ack! "<C-R>"" --
vnoremap <leader>/ y/\V\<<C-R>"\><CR>
vnoremap <leader>? y?\V\<<C-R>"\><CR>
autocmd FileType vimwiki nnoremap <buffer> <Leader>f :Ack!   ~/notebook/notes/<C-B><right><right><right><right><right>

" Swap booleans.
nnoremap <leader>1 :s/false/true/<CR>
nnoremap <leader>0 :s/true/false/<CR>

nnoremap <leader>h :nohl<CR>
nmap <leader>l :set list!<CR>
nnoremap <Leader>c :let &cole=(&cole == 2) ? 0 : 2 <bar> echo 'conceallevel ' . &cole <CR>
nnoremap <leader>r :set relativenumber!<CR>

" Copy current file path to clipboard.
nnoremap gcp :let @+=@%<CR>

" Copy current git branch to clipboard.
nnoremap <leader>cb :!git cp<CR><CR>

" Open active buffer's folder in netrw.
nnoremap <silent> -- :Ex<CR>

nnoremap <silent> =ie =<Plug>(textobj-entire-i)``zz

nnoremap [s i<Space><Esc>l
nnoremap ]s a<Space><Esc>h

nnoremap n nzz
nnoremap N Nzz
nnoremap <C-u> <C-u>zz
nnoremap <C-d> <C-d>zz
nmap ]q :cn<CR>zz
nmap [q :cN<CR>zz

" Move visual selection
vnoremap J :m '>+1<CR>gv=gv
vnoremap K :m '<-2<CR>gv=gv

" Forgiving mappings
" ------------------
cmap Qa qa
cmap Wq wq

" Notes (VimWiki) management
" --------------------------
nnoremap <leader>np :!notes p<CR>
nnoremap <leader>nf :!notes f<CR>

" CoC mappings
" ------------

" Remap keys for gotos
nmap <silent> <leader>gd <Plug>(coc-definition)
nmap <silent> <leader>gy <Plug>(coc-type-definition)
nmap <silent> <leader>gi <Plug>(coc-implementation)
nmap <silent> <leader>gr <Plug>(coc-references)

nmap <silent> [g <Plug>(coc-diagnostic-prev)
nmap <silent> ]g <Plug>(coc-diagnostic-next)

nnoremap <silent> K :call <SID>show_documentation()<CR>

" Personally used for local scope symbol renaming.
nmap <leader>ln <Plug>(coc-rename)
" Project wide rename of current symbol.
nnoremap <leader>pr :CocSearch <C-R>=expand('<cword>')<CR><CR>

" Fix autofix problem of current line
nmap <leader>af  <Plug>(coc-fix-current)

" CoC snippets mappings
" ---------------------

" Use <C-l> for trigger snippet expand.
imap <C-l> <Plug>(coc-snippets-expand)

" Use <C-j> for trigger snippet expand.
vmap <C-l> <Plug>(coc-snippets-select)

" vim-easy-align mappings
" -----------------------

" Interactive mode
xmap ga <Plug>(EasyAlign)
nmap ga <Plug>(EasyAlign)

" VimWiki
" -------
vmap <leader><leader> ygv<CR>%la./<esc>f)i.md<esc>mmvi)gugv:s/\%V /-/ge<CR>:w<CR>gv<esc><CR>i# <C-r>"<CR><CR><esc>:w<CR>i

" GotoSymbol
" ----------
nmap <leader>@ :GotoSymbol 



" AUTOCOMMANDS
" ============

autocmd VimEnter * nested call MyVimEnter()

" Use zsh rather
autocmd vimenter * let &shell='/bin/zsh -i'

" Outside vim file changes tracking
autocmd CursorHold,CursorHoldI * silent! checktime
autocmd FileChangedShellPost *
  \ echohl WarningMsg | echo "File changed on disk. Buffer reloaded." | echohl None

autocmd ColorScheme * highlight CursorLineNr ctermbg=magenta ctermfg=white guibg=magenta guifg=white
autocmd ColorScheme * highlight Cursor ctermbg=yellow ctermfg=black guibg=yellow guifg=black
autocmd ColorScheme * highlight ColorColumn ctermbg=darkgrey guibg=#073642

autocmd VimResized * wincmd =

autocmd BufNewFile,BufRead *.md setlocal filetype=markdown
autocmd BufNewFile,BufRead *.md setlocal textwidth=80

" netrw
augroup netrw_mappings
  autocmd!
  autocmd filetype netrw call NetrwMappings()
augroup END

" emmet-vim
autocmd FileType html,hbs,css,scss EmmetInstall

" vimwiki
autocmd BufRead */notebook/notes/index.md silent !notes f
autocmd FileType vimwiki autocmd BufWritePost <buffer> silent !notes p




" COMMANDS
" ========

" fzf commands
" ------------

command! -bang -nargs=? -complete=dir Files
  \ call fzf#vim#files(<q-args>, fzf#vim#with_preview(), <bang>0)

command! Folders call fzf#run(fzf#wrap({'source': 'find * -type d \( ! -path "node_modules/*" \)'}))

command! NodeModules call fzf#run(fzf#wrap({'source': 'find node_modules/* -type d'}))

command! DeleteBuffers call fzf#run(fzf#wrap({
  \ 'source': s:list_buffers(),
  \ 'sink*': { lines -> s:delete_buffers(lines) },
  \ 'options': '--multi --reverse --bind ctrl-a:select-all+accept'
\ }))

" formatting commands
" -------------------

command! -range=% -nargs=0 Tabs2SpacesOfTwo execute '<line1>,<line2>s#^\t\+#\=repeat(" ", len(submatch(0))*2)'
command! -range=% -nargs=0 SpacesOfTwo2Tabs execute '<line1>,<line2>s#^\( \{2\}\)\+#\=repeat("\t", len(submatch(0))/2)'
command! -range=% -nargs=0 Tabs2SpacesOfFour execute '<line1>,<line2>s#^\t\+#\=repeat(" ", len(submatch(0))*4)'
command! -range=% -nargs=0 SpacesOfFour2Tabs execute '<line1>,<line2>s#^\( \{4\}\)\+#\=repeat("\t", len(submatch(0))/4)'





" STATUSLINE
" ==========
 
" Preview
" -------------------------------------------------
" W1・<vim>       master・☰ 98%・362,1  .vimrc [+]
" -------------------------------------------------
set statusline=%#StatuslineCustom#
set statusline+=\ W%{winnr()}・
set statusline+=%{len(&filetype)?'<'.&filetype.'>':''}
set statusline+=%=
set statusline+=%{exists('g:loaded_fugitive')&&len(FugitiveHead())?'\ '.FugitiveHead():''}
set statusline+=・☰\ 
set statusline+=%P・
set statusline+=%l,
set statusline+=%c
set statusline+=\ 
set statusline+=%#StatuslineFilename#
set statusline+=\ %t\ 
set statusline+=%#ErrorMsg#%m