build: add nix dev environment (#26)

.envrc

@@ -0,0 +1 @@
+use flake . -Lv

.gitignore

@@ -1,3 +1,5 @@
 todo.norg
 .libraries/
 .luarc.json
+.direnv
+result

CONTRIBUTING.md

@@ -50,3 +50,18 @@ These two steps can be executed together with
 ```bash
 make dev_setup
 ```
+
+## Nix dev environment
+
+For nix users, all of these tools are made available in a dev shell.
+
+Run
+```bash
+nix develop
+```
+
+You can test-drive a minimal Neovim package with only neocomplete.nvim and its dependencies
+installed by running
+```bash
+nix run .#nvim
+```

flake.nix

@@ -0,0 +1,73 @@
+{
+  description = "neocomplete.nvim package + dev environment";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
+    flake-parts.url = "github:hercules-ci/flake-parts";
+    gen-luarc.url = "github:mrcjkb/nix-gen-luarc-json";
+  };
+
+  outputs = inputs @ {
+    self,
+    nixpkgs,
+    flake-parts,
+    gen-luarc,
+    ...
+  }:
+    flake-parts.lib.mkFlake {inherit inputs;} {
+      systems = [
+        "x86_64-linux"
+        "x86_64-darwin"
+        "aarch64-darwin"
+      ];
+      perSystem = {system, ...}: let
+        pkgs = import nixpkgs {
+          inherit system;
+          overlays = [
+            gen-luarc.overlays.default
+          ];
+        };
+        luarc = pkgs.mk-luarc {
+          nvim = pkgs.neovim-unwrapped;
+        };
+      in {
+        devShells.default = pkgs.mkShell {
+          name = "lua devShell";
+          shellHook = ''
+            ln -fs ${pkgs.luarc-to-json luarc} .luarc.json
+          '';
+          buildInputs = with pkgs; [
+            lua-language-server
+            stylua
+            alejandra
+            (lua5_1.withPackages (ps:
+              with ps; [
+                luarocks
+                busted
+                luacheck
+                fzy
+                nlua
+              ]))
+          ];
+        };
+
+        packages = rec {
+          default = neocomplete-nvim;
+          neocomplete-nvim = pkgs.vimUtils.buildVimPlugin {
+            pname = "neocomplete.nvim";
+            version = "dev";
+            src = self;
+          };
+          nvim = let
+            config = pkgs.neovimUtils.makeNeovimConfig {
+              plugins = with pkgs; [
+                neocomplete-nvim
+                fzy
+              ];
+            };
+          in
+            pkgs.wrapNeovimUnstable pkgs.neovim-unwrapped config;
+        };
+      };
+    };
+}